Add 方法 - Microsoft Excel Visual Basic 2002 参考

返回介绍

Add 方法

发布于 2019-08-07 字数 67257 浏览 790 评论 0

全部显示

Add 方法

应用于 AddIns 对象的 Add 方法。

将新加载宏文件添加到加载宏列表中。返回 AddIn 对象。

expression.Add(FileName, CopyFile)

expression 必需。该表达式返回一个 AddIns 对象。

Filename String 类型,必需。包含要添加到加载宏管理器列表中的加载宏的文件名称。

CopyFile Variant 类型,可选。如果加载宏文件在硬盘上,则忽略本参数。在加载宏处于可移动介质(软盘或光盘)上的情况下,如果为 True,就将该加载宏复制到硬盘上;如果为 False,则将加载宏保留在可移动介质上。如果省略本参数,Microsoft Excel 将弹出对话框,提示您选择。

说明

该方法不安装新的加载宏。必须设置 Installed 属性以安装加载宏。

应用于 AllowEditRanges 对象的 Add 方法。

在受保护的工作表中添加可以编辑的单元格区域。返回 AllowEditRange 对象。

expression.Add(Title, Range, Password)

expression 必需。该表达式返回一个 AllowEditRanges 对象。

Title String 类型,必需。单元格区域的标题。

Range Range 对象,必需。允许编辑的单元格区域。

Password Variant 类型,可选。单元格区域的密码。

应用于 CalculatedFields 对象的 Add 方法。

创建新的计算字段。返回 PivotField 对象。

expression.Add(Name, Formula, UseStandardFormula)

expression 必需。该表达式返回一个 CalculatedFields 对象。

Name String 类型,必需。字段的名称。

Formula String 类型,必需。字段的公式。

UseStandardFormula Variant 类型,可选。如果向上兼容,则该值为 False(默认值)。对于包含在任意字段名称参数中的字符串来说,该值为 True,并将被解释为已由标准美国英语进行了格式设置,而非本地设置。

应用于 CalculatedItems 对象的 Add 方法。

新建计算项。返回 PivotItem 对象。

expression.Add(Name, Formula, UseStandardFormula)

expression 必需。该表达式返回一个 CalculatedItems 对象。

Name String 类型,必需。项的名称。

Formula String 类型,必需。项的公式。

UseStandardFormula Variant 类型,可选。如果向上兼容,则该值为 False(默认值)。对于包含在任意项名称参数中的字符串来说,该值为 True,并将被解释为已由标准美国英语进行了格式设置,而非本地设置。

应用于 CalculatedMembers 对象的 Add 方法。

向数据透视表中添加计算字段或计算项。返回 CalculatedMember 对象。

expression.Add(Name, Formula, SolveOrder, Type)

expression 必需。该表达式返回一个 CalculatedMembers 对象。

Name String 类型,必需。计算成员的名称。

FormulaString 类型,必需。计算成员的公式。

SolveOrderVariant 类型,可选。计算成员的求解次序。

TypeVariant 类型,可选。计算成员的类型。

说明

Formula 参数必须有正确的 MDX(多维表达式)语法语句。Name 参数对于联机分析处理 (OLAP) 提供程序必须是可接受的,并且 Type 参数也需要定义。

如果将本方法的 Type 参数设置为 xlCalculatedSet,则必须调用 AddSet 方法以使新的字段集在数据透视表中可见。

应用于 ChartObjects 对象的 Add 方法。

创建新的嵌入图表。返回 ChartObject 对象。

expression.Add(Left, Top, Width, Height)

expression 必需。该表达式返回一个 ChartObjects 对象。

Left, Top Double 类型,必需。以磅为单位给出新对象的初始坐标,该坐标是相对于工作表上单元格 A1 的左上角或图表的左上角的坐标。

Width, Height Double 类型,必需。以磅为单位给出新对象的初始大小。

应用于 Charts 对象的 Add 方法。

新建图表工作表。返回 Chart 对象。

expression.Add(Before, After, Count)

expression 必需。该表达式返回一个 Charts 对象。

Before Variant 类型,可选。指定工作表对象,新建的工作表将置于此工作表之前。

After Variant 类型,可选。指定工作表对象,新建的工作表将置于此工作表之后。

Count Variant 类型,可选。要新建的工作表数目。默认值为 1。

说明


如果 BeforeAfter 两者均省略,新建的图表工作表将插入到活动工作表之前。

应用于 CustomProperties 对象的 Add 方法。

添加自定义属性信息。返回 CustomProperty 对象。

expression.Add(Name, Value)

expression 必需。该表达式返回一个 CustomProperties 对象。

Name String 类型,必需。自定义属性的名称。

Value Variant 类型,必需。自定义属性的值。

应用于 CustomViews 对象的 Add 方法。

新建自定义视图。返回 CustomView 对象,该对象代表新建视图。

expression.Add(ViewName, PrintSettings, RowColSettings)

expression 必需。该表达式返回一个 CustomViews 对象。

ViewName String 类型,必需。新建视图的名称。

PrintSettings Variant 类型,可选。如果为 True,则在自定义视图中包括打印设置。

RowColSettings Variant 类型,可选。如果为 True,则在自定义视图中包括隐藏行和隐藏列(包括筛选信息)的设置。

应用于 FormatConditions 对象的 Add 方法。

添加新的条件格式。返回 FormatCondition 对象,该对象代表新添加的条件格式。

expression.Add(Type, Operator, Formula1, Formula2)

expression 必需。该表达式返回一个 FormatConditions 对象。

Type XlFormatConditionType 类型,必需。指定条件格式是基于单元格值还是基于表达式。




XlFormatConditionType 可为以下 XlFormatConditionType 常量之一。
xlCellValue 基于单元格值的条件格式。
xlExpression 基于表达式的条件格式。

Operator Variant 类型,可选。条件格式运算符。可为以下 XlFormatConditionOperator 常量之一:xlBetweenxlEqualxlGreaterxlGreaterEqualxlLessxlLessEqualxlNotBetweenxlNotEqual。如果 TypexlExpression,则忽略 Operator 参数。

Formula1 Variant 类型,可选。与条件格式相关的表达式或数值。可为常量、字符串、单元格引用或公式。

Formula2 Variant 类型,可选。当 OperatorxlBetweenxlNotBetween 时,为与条件格式第二部分相关的表达式或数值(否则,则忽略本参数)。可为常量、字符串、单元格引用或公式。

说明

对单个区域定义的条件格式不能超过三个。可用 Modify 方法修改现有的条件格式,或在添加新条件格式前用 Delete 方法删除现有的条件格式。

应用于 HPageBreaks 对象的 Add 方法。

添加水平分页符。返回 HPageBreak 对象。

expression.Add(Before)

expression 必需。该表达式返回一个 HPageBreaks 对象。

Before Object 类型,必需。Range 对象。新的分页符就添加到本参数所指定的区域上方。

应用于 Hyperlinks 对象的 Add 方法。

向指定的区域或图形添加超链接。返回 Hyperlink 对象。

expression.Add(Anchor, Address, SubAddress, ScreenTip, TextToDisplay)

expression 必需。该表达式返回一个 Hyperlinks 对象。

Anchor Object 类型,必需。超链接的位置。可为 Range 对象或 Shape 对象。

Address String 类型,必需。超链接的地址。

SubAddress Variant 类型,可选。超链接的子地址。

ScreenTip Variant 类型,可选。当鼠标指针停留在超链接上时所显示的屏幕提示。

TextToDisplay Variant 类型,可选。要显示的超链接的文本。

说明

指定 TextToDisplay 参数时,文本必须是字符串。

应用于 Names 对象的 Add 方法。

定义新名称。返回 Name 对象。

expression.Add(Name, RefersTo, Visible, MacroType, ShortcutKey, Category, NameLocal, RefersToLocal, CategoryLocal, RefersToR1C1, RefersToR1C1Local)

expression 必需。该表达式返回一个 Names 对象。

Name Variant 类型,可选。如果未指定 NameLocal,则本参数为必需参数。用作名称的文字(以宏语言指定)。名称中不能包含空格,也不能像是单元格引用。

RefersTo Variant 类型,可选。如果未指定其他 RefersTo 参数之一,则本参数为必需参数。说明本名称所引用的内容(用 A1 样式的记号以宏语言指定)。注意,如果引用不存在,则无任何返回值。

Visible Variant 类型,可选。如果为 True,则用常规方式定义名称。如果为 False,则将名称定义为隐藏名称(即该名称在“定义名称”、“粘贴名称”或“定位”对话框中不出现)。默认值为 True

MacroType Variant 类型,可选。宏类型,如下表所示。

















含义
1 自定义函数(Function 过程)
2 宏(也即 Sub 过程)
3 或省略 无(即该名称不引用自定义函数或宏)

ShortcutKey Variant 类型,可选。宏的快捷键。必须是单个字母,例如“z”或“Z”。只用于命令宏。

Category Variant 类型,可选。MacroType 为 1 或 2 时宏或函数的分类。该分类用于“函数向导”。可以用数字(从 1 开始)或名称(以宏语言指定)引用现有的分类。如果指定的分类不存在,Microsoft Excel 将创建新分类。

NameLocal Variant 类型,可选。如果未指定 Name,则本参数为必需参数。用作名称的文字(以宏语言指定)。名称中不能包含空格,也不能像是单元格引用。

RefersToLocal Variant 类型,可选。如果未指定其他 RefersTo 参数之一,则本参数为必需参数。说明本名称所引用的内容(用 A1 样式的记号以宏语言指定)。

CategoryLocal Variant 类型,可选。如果未指定 Category 参数,则本参数为必需参数。以用户语言编写的文本指定自定义函数的分类。

RefersToR1C1 Variant 类型,可选。如果未指定其他 RefersTo 参数之一,则本参数为必需参数。说明本名称所引用的内容(用 R1C1 样式的记号以宏语言指定)。

RefersToR1C1Local Variant 类型,可选。如果未指定其他 RefersTo 参数之一,则本参数为必需参数。说明本名称所引用的内容(用 R1C1 样式的记号以用户语言指定)。

应用于 OLEObjects 对象的 Add 方法。

向工作表中添加新的 OLE 对象。返回 OLEObject 对象。

expression.Add(ClassType, FileName, Link, DisplayAsIcon, IconFileName, IconIndex, IconLabel, Left, Top, Width, Height)

expression 必需。该表达式返回一个 OLEObjects 对象。

ClassType Variant 类型,可选。(必须指定 ClassTypeFileName)。该字符串包含要创建的对象的程序标识符。如果指定了 ClassType 参数,则忽略 FileNameLink 参数。

FileName Variant 类型,可选。(必须指定 ClassTypeFileName 之一)。该字符串指定要创建的 OLE 对象所使用的文件。

Link Variant 类型,可选。如果为 True,则基于 FileName 的新 OLE 对象链接到该文件。如果该对象不是链接方式,则以文件副本方式创建该对象。默认值为 False

DisplayAsIcon Variant 类型,可选。如果为 True,则以图标或正常图片方式之一显示该新 OLE 对象。如果本参数设为 True,则 IconFileNameIconIndex 参数可用于指定图标。

IconFileName Variant 类型,可选。该字符串指定包含要显示的图标的文件。仅当 DisplayAsIcon 参数为 True 时,使用该参数。如果不指定本参数,或者指定文件中不包含图标,则使用该 OLE 类的默认图标。

IconIndex Variant 类型,可选。指定图标文件中包含的图标数目。仅当 DisplayAsIcon 参数为 True 并且 IconFileName 参数引用包含图标的有效文件时,使用该参数。如果由 IconFileName 参数指定的文件中不存在指定索引号的图标,则使用该文件中的第一个图标。

IconLabel Variant 类型,可选。该字符串指定在图标下方显示的标签。仅当 DisplayAsIcon 参数为 True 时,使用该参数。如果省略该参数,或者该参数为空字符串 (“”),则不显示任何标题。

Left,Top Variant 类型,必需。以磅为单位给出新对象的初始坐标,该坐标是相对于工作表上单元格 A1 的左上角或图表的左上角的坐标。

Width,Height Variant 类型,可选。以磅为单位给出 OLE 对象的初始大小。

应用于 Parameters 对象的 Add 方法。

创建新查询参数。返回 Parameter 对象。

expression.Add(Name, iDataType)

expression 必需。该表达式返回一个 Parameters 对象。

Name String 类型,必需。指定查询参数的名称。该参数名称必须与 SQL 语句中参数子句相符。

iDataType Variant 类型,可选。参数的数据类型。可为任意 XlParameterDataType 常量:




xlParamTypeBigInt

xlParamTypeBinary

xlParamTypeBit

xlParamTypeChar

xlParamTypeDate

xlParamTypeDecimal

xlParamTypeDouble

xlParamTypeFloat

xlParamTypeInteger

xlParamTypeLongVarBinary

xlParamTypeWChar

xlParamTypeNumeric

xlParamTypeLongVarChar

xlParamTypeReal

xlParamTypeSmallInt

xlParamTypeTime

xlParamTypeTimeStamp

xlParamTypeTinyInt

xlParamTypeUnknown

xlParamTypeVarBinary

xlParamTypeVarChar

这些值与 ODBC 数据类型相对应。这些值代表 ODBC 驱动程序要接收的数据类型。Microsoft Excel 和 ODBC 驱动程序管理器将对 Microsoft Excel 提供的参数值进行强制转换,使之成为 ODBC 驱动程序接受的正确数据类型。

应用于 Phonetics 对象的 Add 方法。

向指定的单元格中添加拼音文本。

expression.Add(Start, Length, Text)

expression 必需。该表达式返回一个 Phonetics 对象。

Start Long 类型,必需。代表指定单元格中第一个字符的位置。

Length Long 类型,必需。单元格中从 Start 位置到文本末尾的字符个数。

Text String 类型,必需。代表单元格中拼音文本的所有字符。

应用于 PivotCaches 对象的 Add 方法。

PivotCaches 集合中添加一个新的数据透视表缓存。返回 PivotCache 对象。

expression.Add(SourceType, SourceData)

expression 必需。该表达式返回一个 PivotCaches 对象。

SourceType XlPivotTableSourceType 类型,必需。数据透视表缓存数据的源。







XlPivotTableSourceType 可为以下 XlPivotTableSourceType 常量之一。
xlConsolidation
xlDatabase
xlExternal
xlPivotTable
xlScenario

SourceData Variant 类型,可选。表示新的数据透视表缓存中的数据。当 SourceType 不是 xlExternal 时,此参数必需。它可以是一个 Range 对象、一组区域或是代表已有数据透视表名称的一个文本常量。对于外部数据库而言,它应该是一个二元数组。第一个元素表示用于指定数据提供者的连接字符串,第二个元素表示用于获取数据的 SQL 查询字符串。如果指定此参数,则必须同时指定 SourceType

说明

如果没有任何 PivotTable 对象引用某个数据透视表缓存,那么在保存工作簿之前会自动删除该数据透视表缓存。

应用于 PivotFormulas 对象的 Add 方法。

新建数据透视表公式。返回 PivotFormula 对象。

expression.Add(Formula, UseStandardFormula)

expression 必需。该表达式返回上面的对象之一。

Formula String 类型,必需。新的数据透视表公式。

UseStandardFormula Variant 类型,可选。标准数据透视表公式。

应用于 PivotItems 对象的 Add 方法。

新建数据透视表数据项。

expression.Add(Name)

expression 必需。该表达式返回一个 PivotItems 对象。

Name String 类型,必需。新数据透视表数据项的名称。

应用于 PivotTables 对象的 Add 方法。

添加新的数据透视表。返回 PivotTable 对象。

expression.Add(PivotCache, TableDestination, TableName, ReadData, DefaultVersion)

expression 必需。该表达式返回一个 PivotTables 对象。

PivotCache PivotCache 类型,必需。表示一个数据透视表缓存,而新的数据透视表将基于此缓存创建。缓存用于为报表提供数据。

TableDestination Variant 类型,必需。数据透视表目标区域(工作表中用于放置所生成的报表的区域)左上角的单元格。必须在工作表中(此工作表包含由 expression 所指定的 PivotTables 对象)指定一个目标区域。

TableName Variant 类型,可选。新的数据透视表的名称。

ReadData Variant 类型,可选。如果为 True,则创建的数据透视表缓存中包含外部数据库中的所有记录;此时缓存可能会很大。如果为 False,则允许在实际读取数据之前将有些字段设置为基于服务器的页字段。

DefaultVersion Variant 类型,可选。以前创建数据透视表所使用的 Microsoft Excel 版本。

应用于 PublishObjects 对象的 Add 方法。

创建一个对象,该对象代表保存在 Web 页上的文档中的项目。当对 Microsoft Excel 中的文档进行了一些自动修订时,这些对象可帮助随后对 Web 页进行的更新。返回 PublishObject 对象。

expression.Add(SourceType, Filename, Sheet, Source, HtmlType, DivID, Title)

expression 必需。该表达式返回一个 PublishObjects 对象。

SourceTypeXlSourceType 类型,必需。源的类型。










XlSourceType 可为以下 XlSourceType 常量之一。表示源对象。
xlSourceAutoFilter 自动筛选区域。
xlSourceChart 图表。
xlSourcePivotTable 数据透视表。
xlSourcePrintArea 选定要打印的单元格区域。
xlSourceQuery 查询表(外部数据区域)。
xlSourceRange 单元格区域。
xlSourceSheet 整张工作表。
xlSourceWorkbook 工作簿。

Filename String 类型,必需。用于保存源对象的 URL(在 Intranet 或 Web 上)或路径(本地或网络上)。

Sheet Variant 类型,可选。保存为 Web 页的工作表名称。

Source Variant 类型,可选。是用来标识数据项的唯一名称,而这些数据项的 SourceType 参数为下列常量之一:xlSourceAutoFilterxlSourceChartxlSourcePivotTablexlSourcePrintAreaxlSourceQueryxlSourceRange。如果 SourceTypexlSourceRange,则 Source 指定的是一个区域,该区域可以是一个已定义的名称。如果 SourceTypexlSourceChartxlSourcePivotTablexlSourceQuery,则 Source 指定的是图表、数据透视表或查询表的名称。

HtmlType Variant 类型,可选。用于指定数据项是保存为某个交互式的 Microsoft Office Web 组件还是静态文本和图像。可为下表所列的 XlHTMLType 常量之一。

































常量 说明
xlSourceAutoFilter “自动筛选”区域
xlSourceChart 图表
xlSourcePivotTable 数据透视表
xlSourcePrintArea 选定的用于打印的单元格区域
xlSourceQuery 查询表(外部数据区域)
xlSourceRange 单元格区域
xlSourceSheet 整张工作表

DivID Variant 类型,可选。在 HTML DIV 标记中使用的唯一标识符,它用于标识 Web 页上的项。

Title Variant 类型,可选。Web 页的标题。

应用于 QueryTables 对象的 Add 方法。

新建一个查询表。返回 QueryTable 对象,该对象代表新建的查询表。

expression.Add(Connection, Destination, Sql)

expression 必需。该表达式返回一个 QueryTables 对象。

Connection Variant 类型,必需。查询表的数据源。可为以下情形之一:


  • 一个包含 OLE DB 或 ODBC 连接字符串的字符串。ODBC 连接字符串的形式为“ODBC;<连接字符串>”。

  • 一个 QueryTable 对象,该对象表示查询信息的复制来源,包括连接字符串和 SQL 文本,但不包括 Destination 区域。如果指定 QueryTable 对象,则忽略 Sql 参数。

  • 一个 ADO 或 DAO RecordSet 对象。可从 ADO 或 DAO 记录集中读取数据。Microsoft Excel 将记录集保留到删除该查询表或者 SQL 连接发生更改时为止。不能对查询结果表进行编辑。

  • 一个 Web 查询,是“URL;<url>”形式的字符串,其中“URL;”是必需的,但不进行本地化,字符串的其余部分作为 Web 查询的 URL。

  • 数据查找程序。是“FINDER;<数据查找程序文件路径>”形式的字符串,其中“FINDER;”是必需的,但不进行本地化。字符串的其余部分为数据查找程序文件(*.dqy 或 *.iqy)的路径和名称。使用 Add 方法时将读取该文件;之后,对查询表的 Connection 属性的调用将返回以“ODBC;”或“URL;”开头的字符串,视具体的调用而定。

  • 一个文本文件。是“TEXT;<文本文件路径和名称>”形式的字符串,其中 TEXT 是必需的,但不进行本地化。

Destination Range 类型,必需。查询表目标区域左上角单元格(放置生成的查询表的区域)。目标区域必须在包含 expression 指定的 QueryTables 对象的工作表上。

Sql Variant 类型,可选。在 ODBC 数据源上运行的 SQL 查询字符串。当使用的数据源为 ODBC 数据源时该参数可选(如果不在此处指定该参数,则应该在查询表刷新之前使用查询表的 Sql 属性进行设置)。当将 QueryTable 对象、文本文件、或是 ADO 或 DAO Recordset 对象指定为数据源时不能使用该参数。

说明

由本方法创建的查询将在调用 Refresh 方法后运行。

应用于 RecentFiles 对象的 Add 方法。

向最近使用的文件列表中添加文件。返回 RecentFile 对象。

expression.Add(Name)

expression 必需。该表达式返回一个 RecentFiles 对象。

Name String 类型,必需。文件名。

应用于 Scenarios 对象的 Add 方法。

新建方案并将其添加到当前工作表可用的方案列表中。返回一个 Scenario 对象。

expression.Add(Name, ChangingCells, Values, Comment, Locked, Hidden)

expression 必需。该表达式返回一个 Scenarios 对象。

Name String 类型,必需。方案名。

ChangingCells Variant 类型,必需。指向方案的可变单元格的 Range 对象。

Values Variant 类型,可选。包含 ChangingCells 中指定的单元格方案值的数组。如果省略本参数,就假定方案值是 ChangingCells 单元格中的当前值。

Comment Variant 类型,可选。指定方案的注释文本的字符串。添加新方案时,作者的名字和日期自动添加在注释文本的开始部分。

Locked Variant 类型,可选。若指定为 True,则锁定方案以防更改。默认值为 True

Hidden Variant 类型,可选。若指定为 True,则隐藏方案。默认值为 False

说明

方案名称必须是唯一的;如果试图用已经在使用的名称创建方案,Microsoft Excel 会产生错误。

应用于 SeriesCollection 对象的 Add 方法。

SeriesCollection 集合添加一个或多个新数据系列。

expression.Add(Source, Rowcol, SeriesLabels, CategoryLabels, Replace)

expression 必需。该表达式返回一个 SeriesCollection 对象。

Source Variant 类型,必需。新数据,可用 Range 对象或数据点数组指定。

Rowcol XlRowCol 类型,可选。指定新数据点的值是位于指定区域的行中还是列中。




XlRowCol 可为以下 XlRowCol 常量之一。
xlColumns 默认值
xlRows

SeriesLabels Variant 类型,可选。如果 Source 为数组,则忽略本参数。如果区域中第一行或第一列包含数据系列的名称,则该值为 True。如果第一行或第一列包含数据系列的第一个数据点,则该值为 False。如果省略本参数,Microsoft Excel 就试图从第一行或第一列中的内容判断系列名称的位置。

CategoryLabels Variant 类型,可选。如果 Source 为数组,则忽略本参数。如果区域中第一行或第一列包含分类标签的名称,则该值为 True。如果第一行或第一列包含数据系列的第一个数据点,则该值为 False。如果省略本参数,Microsoft Excel 就试图从第一行或第一列中的内容判断分类标签的位置。

Replace Variant 类型,可选。如果 CategoryLabelsTrueReplaceTrue,那么指定的分类将取代当前系列中存在的分类。如果 ReplaceFalse,现存的分类将保留。默认值为 False

说明

本方法对数据透视图报表无效。

应用于 SheetsWorksheets 对象的 Add 方法。

新建工作表、图表或宏表。新建的工作表将成为活动工作表。

expression.Add(Before, After, Count, Type)

expression 必需。该表达式返回上面的对象之一。

Before Variant 类型,可选。指定工作表对象,新建的工作表将置于此工作表之前。

After Variant 类型,可选。指定工作表对象,新建的工作表将置于此工作表之后。

Count Variant 类型,可选。要新建的工作表的数目。默认值为 1。

Type Variant 类型,可选。指定工作表类型。可为以下 XlSheetType 常量之一:xlWorksheetxlChartxlExcel4MacroSheetxlExcel4IntlMacroSheet。默认值为 xlWorksheet

说明

如果 BeforeAfter 两者均省略,则新建的工作表将插入到活动工作表之前。

应用于 SmartTags 对象的 Add 方法。

添加智能标记。返回 SmartTag 对象。

expression.Add(SmartTagType)

expression 必需。该表达式返回一个 SmartTags 对象。

SmartTagType String 类型,必需。智能标记的类型。

应用于 Styles 对象的 Add 方法。

新建样式并将其添加到当前工作簿的可用样式列表中。返回 Style 对象。

expression.Add(Name, BasedOn)

expression 必需。该表达式返回一个 Styles 对象。

Name String 类型,必需。新样式的名称。

BasedOn Variant 类型,可选。引用某单元格的 Range 对象,新样式即基于该单元格生成。如果省略本参数,就基于“常规” 样式建立新样式。

说明

如果指定名称的样式已经存在,该方法将基于 BasedOn 参数指定的单元格重新定义该存在的样式。下例基于活动单元格重新定义“常规”样式。

ActiveWorkbook.Styles.Add Name := "Normal", _
 BasedOn := ActiveCell

应用于 Trendlines 对象的 Add 方法。

创建新的趋势线。返回 Trendline 对象。

expression.Add(Type, Order, Period, Forward, Backward, Intercept, DisplayEquation, DisplayRSquared, Name)

expression 必需。该表达式返回一个 Trendlines 对象。

Type XlTrendlineType 类型,可选。趋势线类型。








XlTrendlineType 可为以下 XlTrendlineType 常量之一。
xlExponential
xlLinear 默认值
xlLogarithmic
xlMovingAvg
xlPolynomial
xlPower

Order Variant 类型,可选。如果 TypexlPolynomial,本参数为必需参数。趋势线顺序。必须为 2 到 6 之间的整数(包括 2 和 6)。

Period Variant 类型,可选。如果 TypexlMovingAvg,本参数为必需参数。趋势线周期。必须为大于 1,而小于正添加趋势线的数据系列中数据点个数的整数。

Forward Variant 类型,可选。趋势线向前延伸的周期数目(或散点图中的单位个数)。

Backward Variant 类型,可选。趋势线向后延伸的周期数目(或散点图中的单位个数)。

Intercept Variant 类型,可选。趋势线的截距。如果省略该参数,则回归分析将自动设置截距。

DisplayEquation Variant 类型,可选。如果为 True,则在图表中显示趋势线的公式(与 R 平方值显示在同一数据标签中)。默认值为 False

DisplayRSquared Variant 类型,可选。如果为 True,则在图表中显示趋势线的 R 平方值(与公式显示在同一数据标签中)。默认值为 False

Name Variant 类型,可选。作为文本的趋势线的名称。如果省略该参数,由 Microsoft Excel 自动生成名称。

应用于 UserAccessList 对象的 Add 方法。

添加用户访问列表。返回一个 UserAccess 对象。

expression.Add(Name, AllowEdit)

expression 必需。该表达式返回一个 UserAccessList 对象。

Name String 类型,必需。用户访问列表的名称。

AllowEdit Boolean 类型,必需。如果为 True,则允许可访问列表中的用户编辑受保护工作表上的可编辑单元格区域。

应用于 Validation 对象的 Add 方法。

向指定区域内添加数据有效性检验。

expression.Add(Type, AlertStyle, Operator, Formula1, Formula2)

expression 必需。该表达式返回一个 Validation 对象。

TypeXlDVType 类型,必需。数据有效性类型。










XlDVType 可为以下 XlDVType 常量之一。
xlValidateCustom
xlValidateDate
xlValidateDecimal
xlValidateInputOnly
xlValidateList
xlValidateTextLength
xlValidateTime
xlValidateWholeNumber

AlertStyle Variant 类型,可选。有效性检验警告样式。可为以下 XlDVAlertStyle 常量之一:xlValidAlertInformationxlValidAlertStopxlValidAlertWarning

Operator Variant 类型,可选。数据有效性运算符。可为以下 XlFormatConditionOperator 常量之一:xlBetween、xlEqual、xlGreater、xlGreaterEqual、xlLess、xlLessEqual、xlNotBetweenxlNotEqual

Formula1 Variant 类型,可选。数据有效性公式的第一部分。

Formula2 Variant 类型,可选。当 OperatorxlBetweenxlNotBetween 时,数据有效性公式的第二部分(其他情况下,此参数被忽略)。

说明

Add 方法所要求的参数依有效性检验的类型而定,如下表所示。





















数据有效性类型 参数
xlValidateCustom Formula1 必需,忽略 Formula2Formula1 必须包含一个表达式,数据项有效时该表达式取值为 True,而数据项无效时取值为 False
xlInputOnly 能使用 AlertStyleFormula1Formula2 参数。
xlValidateList Formula1 必需,忽略 Formula2Formula1 必须包含以逗号分隔的取值列表,或引用此列表的工作表。
xlValidateWholeNumberxlValidateDatexlValidateDecimalxlValidateTextLengthxlValidateTime 必须指定 Formula1Formula2 之一,或两者均指定。


应用于 VPageBreaks 对象的 Add 方法。

添加垂直分页符。返回 VPageBreak 对象。

expression.Add(Before)

expression 必需。该表达式返回一个 VPageBreaks 对象。

Before Object 类型,必需。Range 对象。新的分页符将添加到本参数所指定的区域左方。

应用于 Watches 对象的 Add 方法。

添加在重新计算工作表时要跟踪的区域。返回 Watch 对象。

expression.Add(Source)

expression 必需。该表达式返回一个 Watches 对象。

Source Variant 类型,必需。单元格区域的源。

应用于 Workbooks 对象的 Add 方法。

新建工作簿。新建的工作簿将成为活动工作簿。返回 Workbook 对象。

expression.Add(Template)

expression 必需。该表达式返回一个 Workbooks 对象。

Template Variant 类型,可选。确定如何创建工作簿。如果本参数为指定一现有 Microsoft Excel 文件名的字符串,那么创建新工作簿将以该指定的文件作为模板。如果本参数为常量,新工作簿将包含指定类型的单张工作表。可为以下 XlWBATemplate 常量之一:xlWBATChartxlWBATExcel4IntlMacroSheetxlWBATExcel4MacroSheetxlWBATWorksheet。如果省略本参数,Microsoft Excel 将创建包含一定数目的空白工作表的工作簿(该数目由 SheetsInNewWorkbook 属性设置)。

说明

如果 Template 参数指定的是文件,则该文件名可包含路径。

示例

应用于 AddIns 对象。

本示例从 A 驱动器中添加加载宏 Myaddin.xla。运行本示例后,Microsoft Excel 将把文件 A:\Myaddin.xla 复制到硬盘上的 Library 文件夹中,并将该加载宏的标题添加到“加载宏”对话框的列表中。

UseAddIn()
    Set myAddIn = AddIns.Add(Filename:="A:\MYADDIN.XLA", _
        CopyFile:=True)
    MsgBox myAddIn.Title & " has been added to the list"
End Sub

应用于 AllowEditRanges 对象。

本示例允许编辑活动工作表上的单元格区域 A1:A4,并通知用户,然后更改指定区域的密码并通知用户所做的更改。

Sub UseChangePassword()
    Dim wksOne As Worksheet
    Set wksOne = Application.ActiveSheet
    ' Protect the worksheet.
    wksOne.Protect
    ' Establish a range that can allow edits
    ' on the protected worksheet.
    wksOne.Protection.AllowEditRanges.Add _
        Title:="Classified", _
        Range:=Range("A1:A4"), _
        Password:="secret"
    MsgBox "Cells A1 to A4 can be edited on the protected worksheet."
    ' Change the password.
    wksOne.Protection.AllowEditRanges(1).ChangePassword _
        Password:="moresecret"
    MsgBox "The password for these cells has been changed."
End Sub

应用于 CalculatedFields 对象。

本示例向第一张工作表上的第一张数据透视表添加计算字段。

Worksheets(1).PivotTables(1).CalculatedFields.Add "PxS", _
 "= Product * Sales"

应用于 CalculatedMembers 对象。

下面的示例向数据透视表中添加集合,假定数据透视表已存在于活动工作表中。

Sub UseAddSet()
Dim pvtOne As PivotTable
Dim strAdd As String
Dim strFormula As String
Dim cbfOne As CubeField
Set pvtOne = ActiveSheet.PivotTables(1)
strAdd = “[MySet]”
strFormula = “‘{[Product].[All Products].[Food].children}'”
‘ Establish connection with data source if necessary.
If Not pvtOne.PivotCache.IsConnected Then pvtOne.PivotCache.MakeConnection
‘ Add a calculated member titled “[MySet]”
pvtOne.CalculatedMembers.Add Name:=strAdd, _
Formula:=strFormula, Type:=xlCalculatedSet
‘ Add a set to the CubeField object.
Set cbfOne = pvtOne.CubeFields.AddSet(Name:=”[MySet]”, _
Caption:=”My Set”)
End Sub

应用于 ChartObjects 对象。

本示例创建新的嵌入图表。

Set co = Sheets("Sheet1").ChartObjects.Add(50, 40, 200, 100)
co.Chart.ChartWizard Source:=Worksheets("Sheet1").Range("A1:B2"), _
    Gallery:=xlColumn, Format:=6, PlotBy:=xlColumns, _
    CategoryLabels:=1, SeriesLabels:=0, HasLegend:=1

应用于 Charts 对象。

本示例创建空白图表工作表,并将其插入到最后一张工作表之前。

ActiveWorkbook.Charts.Add Before:=Worksheets(Worksheets.Count)

应用于 CustomProperties 对象。

本示例向活动工作表添加标识符信息,并将其名称和值返回给用户。

Sub CheckCustomProperties()
    Dim wksSheet1 As Worksheet
    Set wksSheet1 = Application.ActiveSheet
    ' Add metadata to worksheet.
    wksSheet1.CustomProperties.Add _
        Name:="Market", Value:="Nasdaq"
    ' Display metadata.
    With wksSheet1.CustomProperties.Item(1)
        MsgBox .Name & vbTab & .Value
    End With
End Sub

应用于 CustomViews 对象。

本示例在活动工作簿中新建一个自定义视图,并命名为“Summary”。

ActiveWorkbook.CustomViews.Add "Summary", True, True

应用于 FormatConditions 对象。

本示例向单元格区域 E1:E10 中添加条件格式。

With Worksheets(1).Range("e1:e10").FormatConditions _
    .Add(xlCellValue, xlGreater, "=$a$1")
    With .Borders
        .LineStyle = xlContinuous
        .Weight = xlThin
        .ColorIndex = 6
    End With
    With .Font
        .Bold = True
        .ColorIndex = 3
    End With
End With

应用于 HPageBreaks 对象。

本示例在单元格 F25 上方添加水平分页符,在其左方添加垂直分页符。

With Worksheets(1)
    .HPageBreaks.Add .Range("F25")
    .VPageBreaks.Add .Range("F25")
End With

应用于 Hyperlinks 对象。

本示例向单元格 A5 添加超链接。

With Worksheets(1)
    .Hyperlinks.Add Anchor:=.Range("a5"), _
        Address:="http://example.microsoft.com", _
        ScreenTip:="Microsoft Web Site", _
        TextToDisplay:="Microsoft"
End With

本示例向单元格 A5 中添加一个电子邮件超链接。

With Worksheets(1)
    .Hyperlinks.Add Anchor:=.Range("a5"), _
        Address:="mailto:someone@microsoft.com?subject=hello", _
        ScreenTip:="Write us today", _
        TextToDisplay:="Support"
End With

应用于 Names 对象。

本示例为活动工作簿中工作表 Sheet1 上的单元格区域 A1:D3 定义新名称。注意,如果工作表 Sheet1 不存在,则无任何返回值。

Sub MakeRange()
    ActiveWorkbook.Names.Add _
        Name:="tempRange", _
        RefersTo:="=Sheet1!$A$1:$D$3"
End Sub

应用于 OLEObjects 对象。

本示例在 Sheet1 中新建一个 Microsoft Word OLE 对象。

ActiveWorkbook.Worksheets("Sheet1").OLEObjects.Add _
    ClassType:="Word.Document"

本示例为第一张工作表添加命令按钮。

Worksheets(1).OLEObjects.Add ClassType:="Forms.CommandButton.1", _
    Link:=False, DisplayAsIcon:=False, Left:=40, Top:=40, _
    Width:=150, Height:=10

应用于 Parameters 对象。

本示例更改第一张查询表的 SQL 语句。语句“(city=?)”表明此查询为参数查询,城市值被设置为常量“Oakland”。

Set qt = Sheets("sheet1").QueryTables(1)
qt.Sql = "SELECT * FROM authors  WHERE (city=?)"
Set param1 = qt.Parameters.Add("City Parameter", _
    xlParamTypeVarChar)
param1.SetParam xlConstant, "Oakland"
qt.Refresh

应用于 Phonetics 对象。

本示例向活动单元格中添加三个拼音文本字符串。然后将字符类型设置为 Hiragana,将字体颜色设置为蓝色,并将文本设置为可见。

ActiveCell.FormulaR1C1 = "toukyoutotoukyoutotoukyoutoshibuyakushibuyakushibuyakuyoyogiyoyogiyoyogi"
ActiveCell.Phonetics.Add Start:=1, Length:=3, Text:="toukyouto toukyoutotoukyouto toukyoutotoukyouto toukyouto"
ActiveCell.Phonetics.Add Start:=4, Length:=3, Text:="shibuyaku shibuyakushibuyaku shibuyaku"
ActiveCell.Phonetics.CharacterType = xlHiragana
ActiveCell.Phonetics.Font.Color = vbBlue
ActiveCell.Phonetics.Visible = True

应用于 PivotCaches 对象。

本示例在活动工作表的 A3 单元格上新建一个基于 OLAP 提供程序的数据透视表缓存,然后基于该缓存新建一个数据透视表。

Dim cnnConn As ADODB.Connection
Dim rstRecordset As ADODB.Recordset
Dim cmdCommand As ADODB.Command
' Open the connection.
Set cnnConn = New ADODB.Connection
With cnnConn
    .ConnectionString = _
        "Provider=Microsoft.Jet.OLEDB.4.0"
    .Open "C:\perfdate\record.mdb"
End With
' Set the command text.
Set cmdCommand = New ADODB.Command
Set cmdCommand.ActiveConnection = cnnConn
With cmdCommand
    .CommandText = "Select Speed, Pressure, Time From DynoRun"
    .CommandType = adCmdText
    .Execute
End With
' Open the recordset.
Set rstRecordset = New ADODB.Recordset
Set rstRecordset.ActiveConnection = cnnConn
rstRecordset.Open cmdCommand
' Create a PivotTable cache and report.
Set objPivotCache = ActiveWorkbook.PivotCaches.Add( _
    SourceType:=xlExternal)
Set objPivotCache.Recordset = rstRecordset
With objPivotCache
    .CreatePivotTable TableDestination:=Range("A3"), _
        TableName:="Performance"
End With
With ActiveSheet.PivotTables("Performance")
    .SmallGrid = False
    With .PivotFields("Pressure")
        .Orientation = xlRowField
        .Position = 1
    End With
    With .PivotFields("Speed")
        .Orientation = xlColumnField
        .Position = 1
    End With
    With .PivotFields("Time")
        .Orientation = xlDataField
        .Position = 1
    End With
End With
' Close the connections and clean up.
cnnConn.Close
Set cmdCommand = Nothing
Set rstRecordSet = Nothing
Set cnnConn = Nothing

应用于 PivotFormulas 对象。

本示例在第一张工作表上为第一份数据透视表创建一个新数据透视表公式。

Worksheets(1).PivotTables(1).PivotFormulas _
    .Add "Year['1998'] Apples = (Year['1997'] Apples) * 2"

应用于 PivotItems 对象。

本示例在第一张工作表上为第一份数据透视表创建一个新数据透视表项。

Worksheets(1).PivotTables(1).PivotItems("Year").Add "1998"

应用于 PivotTables 对象。

本示例在第一张工作表的 A1 单元格上创建一个基于 OLAP 提供程序的新数据透视表缓存,然后基于该缓存创建一个新的数据透视表。

Dim cnnConn As ADODB.Connection
Dim rstRecordset As ADODB.Recordset
Dim cmdCommand As ADODB.Command
' Open the connection.
Set cnnConn = New ADODB.Connection
With cnnConn
    .ConnectionString = _
        "Provider=Microsoft.Jet.OLEDB.4.0"
    .Open "C:\perfdate\record.mdb"
End With
' Set the command text.
Set cmdCommand = New ADODB.Command
Set cmdCommand.ActiveConnection = cnnConn
With cmdCommand
    .CommandText = "Select Speed, Pressure, Time From DynoRun"
    .CommandType = adCmdText
    .Execute
End With
' Open the recordset.
Set rstRecordset = New ADODB.Recordset
Set rstRecordset.ActiveConnection = cnnConn
rstRecordset.Open cmdCommand
' Create PivotTable cache and report.
Set objPivotCache = ActiveWorkbook.PivotCaches.Add( _
    SourceType:=xlExternal)
Set objPivotCache.Recordset = rstRecordset
ActiveSheet.PivotTables.Add _
    PivotCache:=objPivotCache, _
    TableDestination:=Range("A3"), _
    TableName:="Performance"
With ActiveSheet.PivotTables("Performance")
    .SmallGrid = False
    With .PivotFields("Pressure")
        .Orientation = xlRowField
        .Position = 1
    End With
    With .PivotFields("Speed")
        .Orientation = xlColumnField
        .Position = 1
    End With
    With .PivotFields("Time")
        .Orientation = xlDataField
        .Position = 1
    End With
End With
' Close the connections and clean up.
cnnConn.Close
Set cmdCommand = Nothing
Set rstRecordSet = Nothing
Set cnnConn = Nothing

应用于 PublishObjects 对象。

本示例将活动工作簿中工作表“First Quarter”上的 D5:D9 区域保存到名为“Stockreport.htm”的 Web 页中。使用电子表格组件可增加该 Web 页的交互性。

ActiveWorkbook.PublishObjects.Add( _
    SourceType:=xlSourceRange, _
    Filename:="\\Server2\Q1\Stockreport.htm", _
    Sheet:="First Quarter", _
    Source:="D5:D9", _
    HTMLType:=xlHTMLCalc).Publish

应用于 QueryTables 对象。

本示例基于 ADO 记录集创建一个查询表。为了向后兼容,本示例保留了已有的列排序和筛选设置以及布局信息。

Dim cnnConnect As ADODB.Connection
Dim rstRecordset As ADODB.Recordset
Set cnnConnect = New ADODB.Connection
cnnConnect.Open "Provider=SQLOLEDB;" & _
    "Data Source=srvdata;" & _
    "User ID=testac;Password=4me2no;"
Set rstRecordset = New ADODB.Recordset
rstRecordset.Open _
    Source:="Select Name, Quantity, Price From Products", _
    ActiveConnection:=cnnConnect, _
    CursorType:=adOpenDynamic, _
    LockType:=adLockReadOnly, _
    Options:=adCmdText
With ActiveSheet.QueryTables.Add( _
        Connection:=rstRecordset, _
        Destination:=Range("A1"))
    .Name = "Contact List"
    .FieldNames = True
    .RowNumbers = False
    .FillAdjacentFormulas = False
    .PreserveFormatting = True
    .RefreshOnFileOpen = False
    .BackgroundQuery = True
    .RefreshStyle = xlInsertDeleteCells
    .SavePassword = True
    .SaveData = True
    .AdjustColumnWidth = True
    .RefreshPeriod = 0
    .PreserveColumnInfo = True
    .Refresh BackgroundQuery:=False
End With

本示例向新的查询表中导入固定宽度的文本文件。该文本文件的第一列为 5 个字符宽,作为文本导入。第二列为 4 个字符宽,被跳过。其余部分则导入第三列中,并对其应用常规格式。

Set shFirstQtr = Workbooks(1).Worksheets(1)
Set qtQtrResults = shFirstQtr.QueryTables.Add( _
    Connection := "TEXT;C:\My Documents\19980331.txt",
    Destination := shFirstQtr.Cells(1,1))
With qtQtrResults
    .TextFileParsingType = xlFixedWidth
    .TextFileFixedColumnWidths := Array(5,4)
    .TextFileColumnDataTypes := _
        Array(xlTextFormat, xlSkipColumn, xlGeneralFormat)
    .Refresh
End With

本示例在活动工作表上新建查询表。

sqlstring = "select 96Sales.totals from 96Sales where profit < 5"
connstring = _
    "ODBC;DSN=96SalesData;UID=Rep21;PWD=NUyHwYQI;Database=96Sales"
With ActiveSheet.QueryTables.Add(Connection:=connstring, _
        Destination:=Range("B1"), Sql:=sqlstring)
    .Refresh
End With

应用于 RecentFiles 对象。

本示例将文件 Oscar.xls 添加到最近使用的文件列表中。

Application.RecentFiles.Add Name:="Oscar.xls"

应用于 Scenarios 对象。

本示例向工作表 Sheet1 添加新方案。

Worksheets("Sheet1").Scenarios.Add Name:="Best Case", _
 ChangingCells:=Worksheets("Sheet1").Range("A1:A4"), _
 Values:=Array(23, 5, 6, 21), _
 Comment:="Most favorable outcome."

应用于 SeriesCollection 对象。

本示例在 Chart1 中新建数据系列。新系列的数据源位于 Sheet1 的单元格区域 B1:B10 中。

Charts("Chart1").SeriesCollection.Add _
    Source:=ActiveWorkbook.Worksheets("Sheet1").Range("B1:B10")

本示例在工作表 Sheet1 上的嵌入图表中新建数据系列。

Worksheets("Sheet1").ChartObjects(1).Activate
ActiveChart.SeriesCollection.Add _
    Source:=Worksheets("Sheet1").Range("B1:B10")

应用于 SheetsWorkSheets 对象。

本示例将新建工作表插入到活动工作簿的最后一张工作表之前。

ActiveWorkbook.Sheets.Add Before:=Worksheets(Worksheets.Count)

应用于 SmartTags 对象。

本示例向单元格 A1 添加标题为 MSFT 的智能标记,然后向智能标记添加名为 Market、值为 Nasdaq 的附加元数据,并将属性值返回给用户。本示例假定主机系统已连至 Internet。

Sub UseProperties()
    Dim strLink As String
    Dim strType As String
    ' Define smart tag variables.
    strLink = "urn:schemas-microsoft-com:smarttags#stocktickerSymbol"
    strType = "stockview"
    Range("A1").Formula = "MSFT"
    ' Add a property for MSFT smart tag and define its value.
    Range("A1").SmartTags.Add(strLink).Properties.Add _
        Name:="Market", Value:="Nasdaq"
    ' Notify the user of the smart tag's value.
    MsgBox Range("A1").SmartTags.Add(strLink).Properties("Market").Value
End Sub

应用于 Styles 对象。

本示例基于工作表 Sheet1 中的单元格 A1 定义新样式。

With ActiveWorkbook.Styles.Add(Name:="theNewStyle")
    .IncludeNumber = False
    .IncludeFont = True
    .IncludeAlignment = False
    .IncludeBorder = False
    .IncludePatterns = False
    .IncludeProtection = False
    .Font.Name = "Arial"
    .Font.Size = 18
End With

应用于 Trendlines 对象。

本示例在 Chart1 中新建线性趋势线。

ActiveWorkbook.Charts("Chart1").SeriesCollection(1).Trendlines.Add

应用于 Validation 对象。

本示例向单元格 E5 添加数据有效性检验。

With Range("e5").Validation
    .Add Type:=xlValidateWholeNumber, _
        AlertStyle:= xlValidAlertStop, _
        Operator:=xlBetween, Formula1:="5", Formula2:="10"
    .InputTitle = "Integers"
    .ErrorTitle = "Integers"
    .InputMessage = "Enter an integer from five to ten"
    .ErrorMessage = "You must enter a number from five to ten"
End With

应用于 VPageBreaks 对象。

本示例在单元格 F25 上方添加水平分页符,在其左方添加垂直分页符。

With Worksheets(1)
 .HPageBreaks.Add .Range("F25")
 .VPageBreaks.Add .Range("F25")
End With

应用于 Watches 对象。

本示例在单元格 A3 中创建求和公式,并将该单元格添加至监视工具中。

Sub AddWatch()
    With Application
        .Range("A1").Formula = 1
        .Range("A2").Formula = 2
        .Range("A3").Formula = "=Sum(A1:A2)"
        .Range("A3").Select
        .Watches.Add Source:=ActiveCell
    End With
End Sub

应用于 Workbooks 对象。

本示例新建工作簿。

Workbooks.Add

上一篇:ActivatePrevious 方法

下一篇:AddCallout 方法

发布评论

需要 登录 才能够评论, 你可以免费 注册 一个本站的账号。

支持 Markdown 语法,需要帮助?

目前还没有任何评论,快来抢沙发吧!